mysql的长连接问题

Stanford

目前用的易语言的mysql直连
mysql长连接的具体用法是怎么样的
目前是短连接,高频多线程增删查,就是比如几个电脑同时几十次连接和断开
然后软件经常未响应或者崩溃,不确定是不是高频连接断开这个原因

长连接标准写法怎么写的
如何保持在线,防止mysql断开导致软件未响应崩溃
保持在线的话有哪些稳定的方案

半世琉璃

可参考，自己添加以下精易模块就OK
demo.e (90.47 KB, 下载次数: 21)

2023-8-24 19:56 上传

点击文件名下载附件

冬夏

定时执行SQL语句，例如：每隔20分钟执行一次cha询

永痕

易语言 没有完善ORM/数据库框架，你说的事情就是要自己造轮子。首先你需要了解读写数据库是文件IO读写，读写文件本来就不适合多线程。要写一个在一个线程下。你多线程写，又没有完善的连接池组件你不崩谁崩。

智软网络

试下我的智软开发库，内部做了处理，mysql断开会自动连接

智软网络

试下我的智软开发库，内部做了处理，mysql断开会自动连接

乐鱼驴

MySql多线程连接失败解决方案
https://bbs.125.la/forum.php?mod=viewthread&tid=14606876
(出处: 精易论坛)
Mysql连接池 不断线~
https://bbs.125.la/forum.php?mod=viewthread&tid=14613449
(出处: 精易论坛)

半世琉璃

[JavaScript] 纯文本查看 复制代码

.版本 2
.支持库 EThread
.支持库 mysql

.程序集 窗口程序集_窗口1

.子程序 _窗口1_创建完毕

许可证_SQL ＝ 创建进入许可证 ()
SQL.地址 ＝ “127.0.0.1”
SQL.端口 ＝ 3306
SQL.账号 ＝ “root”
SQL.密码 ＝ “root”
SQL.库名 ＝ “demo”
sql_初始化 (真)
sql_读取所有账号 (, , )
启动线程 (&线程_定时事件, , )
返回 (0)  ' 可以根据您的需要返回任意数值


.子程序 线程_定时事件
.局部变量 局_当前时间, 整数型
.局部变量 局_设置间隔_SQL心跳, 整数型, , , ms
.局部变量 局_设置间隔_账号同步, 整数型, , , ms
.局部变量 局_最后执行时间_SQL心跳, 整数型, , , ms
.局部变量 局_最后执行时间_账号同步, 整数型, , , ms

局_设置间隔_SQL心跳 ＝ 5000
局_设置间隔_账号同步 ＝ 10000
连续赋值 (取启动时间 (), 局_最后执行时间_SQL心跳, 局_最后执行时间_账号同步)
.判断循环首 (真)
    局_当前时间 ＝ 取启动时间 ()

    ' ======================    SQL 心跳    ======================
    .如果真 (局_当前时间 － 局_最后执行时间_SQL心跳 ＞ 局_设置间隔_SQL心跳)
        sql_心跳 ()
        局_最后执行时间_SQL心跳 ＝ 取启动时间 ()
    .如果真结束

    ' ====================    账号状态同步    ====================
    .' 如果真 (局_当前时间 － 局_最后执行时间_账号同步 ＞ 局_设置间隔_账号同步)
        ' 功能_同步账号 ()
        ' 局_最后执行时间_账号同步 ＝ 取启动时间 ()
    .如果真结束

.判断循环尾 ()


.子程序 sql_初始化
.参数 失败结束, 逻辑型, 可空
.局部变量 ret, 逻辑型

.如果真 (是否为空 (失败结束))
    失败结束 ＝ 真
.如果真结束
进入许可区 (许可证_SQL)
句柄_mysql ＝ 连接MySql (SQL.地址, SQL.账号, SQL.密码, SQL.库名, SQL.端口)
退出许可区 (许可证_SQL)
.如果真 (句柄_mysql ＝ 0)
    信息框 (“数据库连接失败，请重启软件”, 0, , )
    .判断开始 (失败结束)
        结束 ()
    .默认
        功能_添加日志 (“数据库连接失败，请重启软件”, 真)
    .判断结束

.如果真结束
进入许可区 (许可证_SQL)

.子程序 sql_心跳
.局部变量 ret, 逻辑型

进入许可区 (许可证_SQL)
ret ＝ 执行SQL语句 (句柄_mysql, “SET NAMES 'utf8'”)
退出许可区 (许可证_SQL)
.如果真 (取反 (ret))
    sql_初始化 (假)
.如果真结束


.子程序 sql_读取所有账号, 逻辑型
.参数 参_账号数据, 账号数据, 参考 数组
.局部变量 sql语句, 文本型
.局部变量 执行结果, 逻辑型
.局部变量 new, 账号数据
.局部变量 记录集句柄, 整数型
.局部变量 记录总数, 长整数型
.局部变量 i, 整数型
.局部变量 局_人数, 长整数型
.局部变量 失败, 整数型
.局部变量 a, 整数型
.局部变量 成功, 整数型
.局部变量 isrun, 整数型

重定义数组 (参_账号数据, 假, 0)
sql语句 ＝ “SELECT * FROM sfz_Order WHERE isDelete=0”
进入许可区 (许可证_SQL)
执行结果 ＝ 执行SQL语句 (句柄_mysql, sql语句)
.如果真 (执行结果)
    记录集句柄 ＝ 取记录集 (句柄_mysql)
.如果真结束
退出许可区 (许可证_SQL)

.如果真 (记录集句柄 ≠ 0)
    记录总数 ＝ 取记录集行数 (记录集句柄)
    .如果真 (记录总数 ＞ 0)
        重定义数组 (参_账号数据, 假, 0)
        .计次循环首 (记录总数, i)
            读字段值 (记录集句柄, “a”, new.订单ID)
            读字段值 (记录集句柄, “b”, new.人数)
            读字段值 (记录集句柄, “c”, new.订单类别)
            加入成员 (参_账号数据, new)
            成功 ＝ 成功 ＋ 1
            到下一行 (记录集句柄)
        .计次循环尾 ()
        释放记录集 (记录集句柄)
        返回 (真)
    .如果真结束

.如果真结束

返回 (假)

.子程序 功能_添加日志
.参数 text, 文本型
.参数 是否多线程, 逻辑型

.如果真 (是否多线程)
    进入许可区 (许可证_变量)
.如果真结束
窗口1.编辑框_log.加入文本 (时间_格式化 (取现行时间 (), “”, “hh:mm:ss”, “”, 8) ＋ “ >> ” ＋ text ＋ #换行符)
.如果真 (是否多线程)
    退出许可区 (许可证_变量)
.如果真结束

.版本 2

.全局变量 SQL, SQL连接数据
.全局变量 句柄_mysql, 整数型
.全局变量 许可证_SQL, 整数型
.版本 2

.数据类型 SQL连接数据
    .成员 地址, 文本型
    .成员 端口, 整数型
    .成员 账号, 文本型
    .成员 密码, 文本型
    .成员 库名, 文本型

.数据类型 config
    .成员 句柄_mysql, 整数型