易语言组合框模拟按键的问题 麻烦大神帮看看应该怎么实现

sn7039764

如图 我想在 选择框被选中的时候自动按组合框中选中的按键（组合框中加入了键盘上所有按键） 中间的编辑框就是每过多久按一次了 不一定是60秒 最好能判断下组合框1与2或是更多组合框选中的按键是否冲突

还有个小问题 就是我在执行一直按X键的时候 怎么才能实现选择框选中时候的按键呢 比如我一直在执行按X键 但是过60秒就要执行按一次F1（组合框选中F1时 也可能是选中别的按键） 怎么才能不让他们冲突


另外这是我写的代码 不会调用组合框 只是写了个例子 要用这个命令实现 （用模拟按键命令没效果 所以选择了这个命令）



.版本 2

.子程序 _选择框1_被单击

.如果 (选择框1.选中 ＝ 真)
    键盘_按住虚拟键 (88)
    键盘_按下和弹起时间间隔 (“dx”, 100)
    键盘_弹起虚拟键 (88)

请大神帮改改 怎么实现我上面所说的功能

.版本 2

.子程序 键盘_按下虚拟键, 整数型, 公开, 失败返回0  成功返回1  [追梦]
.参数 键代码, 整数型


.版本 2

.子程序 键盘_弹起虚拟键, 整数型, 公开, 失败返回0  成功返回1  [追梦]
.参数 键代码, 整数型



这是命令参数



求源码........在线等.......

yab8012

精易模块，键盘_消息这个命令
其余的判断多少秒，如果选择框.选中，这些不要详细说了吧

补充内容 (2023-4-14 14:31):
你或者用时钟，每个选择框后面加时钟，时钟周期=前面的时间x1000，周期事情里面用精易模块的键盘_单击，假如有句柄的，用键盘_信息，我上不了易...

sn7039764

yab8012 发表于 2023-4-14 14:00
精易模块，键盘_消息这个命令
其余的判断多少秒，如果选择框.选中，这些不要详细说了吧 ...

能来个源码么大神 我是真的不会写了 难住了

DHeyong

参考例子 精易模块 鼠标_监视_安装

sn7039764

DHeyong 发表于 2023-4-14 14:04
参考例子 精易模块 鼠标_监视_安装

帮写个源码呗 大神

帅气与大侠

完整源码下载： 热键框模块1.0 (1).zip (580.49 KB, 下载次数: 5)

2023-4-14 16:00 上传

点击文件名下载附件
[e=1]
.版本 2
.支持库 spec
.支持库 EThread

.程序集 窗口程序集_启动窗口
.程序集变量 集_热键框按键1, 整数型, , "0"
.程序集变量 集_热键框按键2, 整数型, , "0"

.子程序 __启动窗口_创建完毕

热键框_初始化 (_启动窗口, “热键框”, 到整数 (&热键设置完成回调), 0, )


.子程序 热键设置完成回调, 整数型
.参数 热键框句柄, 整数型
.参数 键代码, 整数型
.参数 功能键状态, 整数型
.参数 快捷键文本指针, 整数型
.局部变量 快捷键文本, 文本型
.局部变量 功能键名, 文本型

快捷键文本 ＝ 指针到文本 (快捷键文本指针)
.如果真 (寻找热键框快捷键文本 (_启动窗口, “热键框”, 快捷键文本) ＝ 真)
    ' 如果已存在相同快捷键，则中断快捷键设置
    返回 (1)
.如果真结束


' 依次将快捷键解析存入数组
.判断开始 (热键框句柄 ＝ 热键框1.取窗口句柄 ())
    解析热键 (集_热键框按键1, 键代码, 功能键状态)

.判断 (热键框句柄 ＝ 热键框2.取窗口句柄 ())
    解析热键 (集_热键框按键2, 键代码, 功能键状态)
.默认

.判断结束

调试输出 (快捷键文本)
返回 (0)

.子程序 解析热键
.参数 键代码数组, 整数型, 参考 数组
.参数 键代码, 整数型
.参数 功能键状态, 整数型
.局部变量 功能键名, 文本型

重定义数组 (集_热键框按键1, 假, 4)
键代码数组 [1] ＝ 键代码
功能键名 ＝ 热键框_取功能键状态名 (功能键状态)
.如果真 (寻找文本 (功能键名, “Ctrl +”, , 假) ≠ -1)
    键代码数组 [2] ＝ #Ctrl键
.如果真结束
.如果真 (寻找文本 (功能键名, “Shift +”, , 假) ≠ -1)
    键代码数组 [3] ＝ #Shift键
.如果真结束
.如果真 (寻找文本 (功能键名, “Alt +”, , 假) ≠ -1)
    键代码数组 [4] ＝ #Alt键
.如果真结束


.子程序 寻找热键框快捷键文本, 逻辑型
.参数 组件窗口, 窗口
.参数 名称前缀, 文本型
.参数 快捷键文本, 文本型
.局部变量 寻找句柄, 整数型
.局部变量 组件数量, 整数型
.局部变量 i, 整数型
.局部变量 热键框, 编辑框
.局部变量 是否找到, 逻辑型

寻找句柄 ＝ 寻找组件 (组件窗口, 名称前缀, “编辑框”, , )
组件数量 ＝ 取找到组件数目 (寻找句柄)
.计次循环首 (组件数量, i)
    热键框 ＝ 取所找到组件 (寻找句柄, i － 1)
    .如果真 (热键框.内容 ＝ 快捷键文本)
        是否找到 ＝ 真
        跳出循环 ()
    .如果真结束

.计次循环尾 ()
清除组件寻找句柄 (寻找句柄)
返回 (是否找到)


.子程序 键盘_组合按键ex, , 公开, 模拟一个组合按键；如:Ctrl+A
.参数 键代码, 整数型, , 键代码；如：A(65)
.参数 功能键码1, 整数型, , 功能键代码；如：ctrl(1) 或 #ctrl
.参数 功能键码2, 整数型, 可空, 功能键代码(可以留空)
.参数 功能键码3, 整数型, 可空, 功能键代码(可以留空)

.如果真 (功能键码3 ≠ 0)
    keybd_event (功能键码3, 0, 0, 0)
.如果真结束

.如果真 (功能键码2 ≠ 0)
    keybd_event (功能键码2, 0, 0, 0)
.如果真结束

.如果真 (功能键码1 ≠ 0)
    keybd_event (功能键码1, 0, 0, 0)
.如果真结束

keybd_event (键代码, 0, 0, 0)

.如果真 (功能键码3 ≠ 0)
    keybd_event (功能键码3, 0, 2, 0)
.如果真结束

.如果真 (功能键码2 ≠ 0)
    keybd_event (功能键码2, 0, 2, 0)
.如果真结束

.如果真 (功能键码1 ≠ 0)
    keybd_event (功能键码1, 0, 2, 0)
.如果真结束

keybd_event (键代码, 0, 2, 0)

.子程序 _选择框1_被单击
.局部变量 线程句柄, 整数型, 静态

.判断开始 (选择框1.选中 ＝ 真)

    连续赋值 (真, 编辑框1.禁止, 热键框1.禁止)
    启动线程 (&按键1, 到整数 (编辑框1.内容), 线程句柄)
.默认

    强制结束线程 (线程句柄)
    连续赋值 (假, 编辑框1.禁止, 热键框1.禁止)
.判断结束


.子程序 _选择框2_被单击
.局部变量 线程句柄, 整数型, 静态

.判断开始 (选择框2.选中 ＝ 真)

    连续赋值 (真, 编辑框2.禁止, 热键框2.禁止)
    启动线程 (&按键2, 到整数 (编辑框2.内容), 按键1线程句柄)
.默认

    强制结束线程 (线程句柄)
    连续赋值 (假, 编辑框2.禁止, 热键框2.禁止)
.判断结束


.子程序 按键1
.参数 延迟时间, 整数型, , 单位是秒

.判断循环首 (延迟时间 ＞ 0)

    调试输出 (集_热键框按键1 [1], 集_热键框按键1 [2], 集_热键框按键1 [3], 集_热键框按键1 [4])



    键盘_组合按键ex (集_热键框按键1 [1], 集_热键框按键1 [2], 集_热键框按键1 [3], 集_热键框按键1 [4])

    程序_延时 (延迟时间, 1)
.判断循环尾 ()

.子程序 按键2
.参数 延迟时间, 整数型, , 单位是秒

.判断循环首 (延迟时间 ＞ 0)

    调试输出 (集_热键框按键2 [1], 集_热键框按键2 [2], 集_热键框按键2 [3], 集_热键框按键2 [4])
    键盘_组合按键ex (集_热键框按键2 [1], 集_热键框按键2 [2], 集_热键框按键2 [3], 集_热键框按键2 [4])

    程序_延时 (延迟时间, 1)
.判断循环尾 ()


[e/]